VBA Code:

'writing the variable identification as curve name
'this is designed for projects where the curve name should be language switchable
'for adding the variable identification to the language table as keyword use the "Language Change Wizward" (category "Language Table")
Public Sub TrendCurveNameVarIdent()
Dim obFuncs As RtFunctions
Dim obFunc As RtFunction
Dim iFunc As Integer
Dim obPics As DynPictures
Dim obPic As DynPicture
Dim obVars As Variables
Dim obCurveVar As Variable
Dim iCurves As Integer
Dim iCurvesConf As Integer
Dim iCurveNamesModif As Integer
'create a object of the function collection
Set obVars = MyWorkspace.ActiveDocument.Variables

'create a object of the picture collection
Set obPics = MyWorkspace.ActiveDocument.DynPictures
'create a object of the function collection
Set obFuncs = MyWorkspace.ActiveDocument.RtFunctions

'loop through all functions
For iFunc = 0 To obFuncs.Count - 1
'create a object of the function
Set obFunc = obFuncs.Item(iFunc)
'check if the object could be created successfully
If Not obFunc Is Nothing Then
'check if the function is a pictureswitch function (tpPicture = 3)
If obFunc.Type = tpPicture Then
'get the linked picture
Set obPic = obPics.Item(obFunc.DynProperties("PictSwitch[0].Picture"))
'check if the linked picture exists
If Not obPic Is Nothing Then
'check if the picture is a ETM picture (5 = Extended trend)
If obPic.Type = 5 Then
'get the number of curves configured in the picture switch function
iCurvesConf = obFunc.DynProperties("PictFilter[0].Curve[-1]")
'loop through the curves
For iCurves = 0 To iCurvesConf - 1
'get the variable linked to this curve
Set obCurveVar = obVars.Item(obFunc.DynProperties("PictFilter[0].Curve[" & iCurves & "].VarInfo.VarName"))
'check if the linked variable exits
If Not obCurveVar Is Nothing Then
'check if a tagname has been configured
If Len(obCurveVar.Tagname) > 0 Then
'check if the curve name is already the variable identification
If StrComp(obCurveVar.Tagname, obFunc.DynProperties("PictFilter[0].Curve[" & iCurves & "].GraphName")) <> 0 Then
'write the variable identification to the curvename
obFunc.DynProperties("PictFilter[0].Curve[" & iCurves & "].GraphName") = obCurveVar.Tagname
iCurveNamesModif = iCurveNamesModif + 1
End If
End If
'release the created object
Set obCurveVar = Nothing
End If
Next iCurves
End If
'release the created object
Set obPic = Nothing
End If
End If
'release the created object
Set obFunc = Nothing
End If
Next iFunc

'release the created objects
Set obFuncs = Nothing
Set obPics = Nothing
Set obVars = Nothing

MsgBox "Curves modyfied: " & iCurveNamesModif
End Sub